Setting up (CHARMM)

Starting from a PDB

For this tutorial, we're going to assume you want to start from a PDB. This can raise some formatting issues, as the PDB format is rarely stuck to exactly, and even the slightest error can cause CHARMM to complain, and fail to read it in. If you have problems, you should compare your PDB file to the one we use here, and make the necessary changes yourself in vi. If you already have a .crd file to use, congratulations! You can safely skip the next section - although you will still need a PDB file to generate a perm.allow for your system automatically.

NOTE: if your system is NOT a standard peptide/protein, you will need to make the perm.allow file manually!

You can download the PDB we're using as the starting point for this tutorial here.

Converting a PDB into CHARMM .crd (CARD) format

In order to run GMIN, OPTIM or PATHSAMPLE using CHARMM, your input must be in CHARMM '.crd' or CARD format. You can do this using scripts form the MMTSB toolset, or just using CHARMM itself.

Here is some example CHARMM input to do this. You will need to change the set pardir line to point to where you have your copy of the svn repository. If you're working within CUC3, this will probably mean simply replacing my CRSID (csw34) with your own.

! CHARMM input to convert a PDB file into a CHARMM .crd (CARD) file
set pardir "/home/csw34/svn/CHARMM31/toppar"
set top "toph19_eef1_perm.inp"
set par "param19_eef1_perm.inp"

! BOMLev sets the level of warnings what do not cause the program to exit. -5 = very lax
BOMLev -5

! PRNLEV sets the ammount of output you get from CHARMM. 5 = high
PRNLEV +5

! Read standard topology and parameter files.
OPEN READ CARD UNIT 1 NAME @pardir/@top
READ RTF CARD UNIT 1
CLOSE UNIT 1

OPEN READ CARD UNIT 2 NAME @pardir/@par
READ PARAMETER CARD UNIT 2
CLOSE UNIT 2

! Generate the PSF for met-enk
READ SEQUence CARD
*
5
TYR GLY GLY PHE MET
GENErate FIRS NTER LAST CTER SETUp

! Read in the PDB file
OPEN UNIT 20 NAME metenk.pdb READ CARD
READ COOR UNIT 20 PDB
CLOSE UNIT 20

! Fill the internal coordinate table
IC FILL PRESERVE
IC PARAMETERS
IC PURGE
IC BUILD

! Write out the .crd (CARD) file
OPEN UNIT 20 NAME metenk.crd WRITE CARD
WRITE COOR UNIT 20 CARD
CLOSE UNIT 20

STOP

Assuming you have CHARMM in your path, and that you are in the directory containing metenk.pdb, you can run this simply using:

 
charmm < pdb2crd.inp

Hopefully this will run just fine. If you wanted to do this for your own system, you would of course need to also modify the PSF section appropriately.