Parameter-scanning script

#!/bin/csh

# need data.template, qsub.template and input.*.crd in the top level directory (from which this script is run) 
# as well as all the other necessary files for the particular type of run (see the cp's below).

foreach temp ( 1.5 2.0 )
   foreach stepsize ( 15 30 )

        set inputseed = 1
        while ($inputseed < 3) # number of independent starting configurations, in files input.*.crd

        if (-d $temp'_'$stepsize'_'$inputseed) then
            # directory already exists
            echo skipping $temp'_'$stepsize'_'$inputseed
        else
            mkdir $temp'_'$stepsize'_'$inputseed
            cp input.$inputseed.crd $temp'_'$stepsize'_'$inputseed/input.crd
            echo TEMPERATURE $temp > $temp'_'$stepsize'_'$inputseed/data
            echo STEP $stepsize 0.0 >> $temp'_'$stepsize'_'$inputseed/data
            cat data.template >> $temp'_'$stepsize'_'$inputseed/data

            #cp coordsinirigid $temp'_'$stepsize'_'$inputseed/
            #cp rbodyconfig $temp'_'$stepsize'_'$inputseed/
            cp 1le0_extended.pdb $temp'_'$stepsize'_'$inputseed/
            cp chemshifts.dat $temp'_'$stepsize'_'$inputseed/
            echo '#PBS -N trpzip.'$temp'_'$stepsize'_'$inputseed > $temp'_'$stepsize'_'$inputseed/qsub.camshift
            cat qsub.template >> $temp'_'$stepsize'_'$inputseed/qsub.camshift

            cd $temp'_'$stepsize'_'$inputseed

            echo submitting $temp'_'$stepsize'_'$inputseed
            qsub qsub.camshift

            cd ..
            sleep 1 # to avoid hammering the queueing system
         endif

         @ inputseed = $inputseed + 1
         end
   end
end